ESP-WROOM-02でNTPクライアント

秋月のＥＳＰ－ＷＲＯＯＭ－０２用２．５４ｍｍピッチ変換基板を使用してWROOM-02をブレッドボードで動作確認

ソースはESP8266用のスケッチブック例「ESP8266WiFi→NTPClient」を使用。
★のところ書き換えた。
※ルータ接続先とパスワード、NTPサーバ、日本時間の+9時間の4箇所
NTPサーバは http://jjy.nict.go.jp/tsp/PubNtp/index.html の公開NTPを参照

/*

 Udp NTP Client

 Get the time from a Network Time Protocol (NTP) time server
 Demonstrates use of UDP sendPacket and ReceivePacket
 For more on NTP time servers and the messages needed to communicate with them,
 see http://en.wikipedia.org/wiki/Network_Time_Protocol

 created 4 Sep 2010
 by Michael Margolis
 modified 9 Apr 2012
 by Tom Igoe
 updated for the ESP8266 12 Apr 2015 
 by Ivan Grokhotkov

 This code is in the public domain.

 */

#include 
#include 

char ssid[] = "*************";  //  your network SSID (name) ★ルータのSSID
char pass[] = "********";       // your network password     ★WIFIの暗号化キー


unsigned int localPort = 2390;      // local port to listen for UDP packets

/* Don't hardwire the IP address or we won't get the benefits of the pool.
 *  Lookup the IP address for the host name instead */
//IPAddress timeServer(129, 6, 15, 28); // time.nist.gov NTP server
IPAddress timeServerIP; // time.nist.gov NTP server address
//const char* ntpServerName = "time.nist.gov";
const char* ntpServerName = "ntp.nict.jp";  // ★日本標準時 に直結した時刻サーバ

const int NTP_PACKET_SIZE = 48; // NTP time stamp is in the first 48 bytes of the message

byte packetBuffer[ NTP_PACKET_SIZE]; //buffer to hold incoming and outgoing packets

// A UDP instance to let us send and receive packets over UDP
WiFiUDP udp;

void setup()
{
  Serial.begin(115200);
  Serial.println();
  Serial.println();

  // We start by connecting to a WiFi network
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, pass);
  
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  Serial.println("Starting UDP");
  udp.begin(localPort);
  Serial.print("Local port: ");
  Serial.println(udp.localPort());
}

void loop()
{
  //get a random server from the pool
  WiFi.hostByName(ntpServerName, timeServerIP); 

  sendNTPpacket(timeServerIP); // send an NTP packet to a time server
  // wait to see if a reply is available
  delay(1000);
  
  int cb = udp.parsePacket();
  if (!cb) {
    Serial.println("no packet yet");
  }
  else {
    Serial.print("packet received, length=");
    Serial.println(cb);
    // We've received a packet, read the data from it
    udp.read(packetBuffer, NTP_PACKET_SIZE); // read the packet into the buffer

    //the timestamp starts at byte 40 of the received packet and is four bytes,
    // or two words, long. First, esxtract the two words:

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]);
    // combine the four bytes (two words) into a long integer
    // this is NTP time (seconds since Jan 1 1900):
    unsigned long secsSince1900 = highWord << 16 | lowWord;
    Serial.print("Seconds since Jan 1 1900 = " );
    Serial.println(secsSince1900);

    // now convert NTP time into everyday time:
    Serial.print("Unix time = ");
    // Unix time starts on Jan 1 1970. In seconds, that's 2208988800:
    const unsigned long seventyYears = 2208988800UL;
    // subtract seventy years:
    //unsigned long epoch = secsSince1900 - seventyYears;
    unsigned long epoch = secsSince1900 - seventyYears + (9 * 60 * 60); // ★日本時間の+9時間に補正
    // print Unix time:
    Serial.println(epoch);


    // print the hour, minute and second:
    Serial.print("The UTC time is ");       // UTC is the time at Greenwich Meridian (GMT)
    Serial.print((epoch  % 86400L) / 3600); // print the hour (86400 equals secs per day)
    Serial.print(':');
    if ( ((epoch % 3600) / 60) < 10 ) {
      // In the first 10 minutes of each hour, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.print((epoch  % 3600) / 60); // print the minute (3600 equals secs per minute)
    Serial.print(':');
    if ( (epoch % 60) < 10 ) {
      // In the first 10 seconds of each minute, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.println(epoch % 60); // print the second
  }
  // wait ten seconds before asking for the time again
  delay(10000);
}

// send an NTP request to the time server at the given address
unsigned long sendNTPpacket(IPAddress& address)
{
  Serial.println("sending NTP packet...");
  // set all bytes in the buffer to 0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialize values needed to form NTP request
  // (see URL above for details on the packets)
  packetBuffer[0] = 0b11100011;   // LI, Version, Mode
  packetBuffer[1] = 0;     // Stratum, or type of clock
  packetBuffer[2] = 6;     // Polling Interval
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // all NTP fields have been given values, now
  // you can send a packet requesting a timestamp:
  udp.beginPacket(address, 123); //NTP requests are to port 123
  udp.write(packetBuffer, NTP_PACKET_SIZE);
  udp.endPacket();
}

実行結果

Connecting to WARPSTAR-460AE2
.......
WiFi connected
IP address: 
192.168.0.4
Starting UDP
Local port: 2390
sending NTP packet...
packet received, length=48
Seconds since Jan 1 1900 = 3735198588
Unix time = 1526242188
The UTC time is 20:09:48

ESP8266は電流の供給がしっかりしていないと、電圧降下によりリセットを繰り返して動作が不安定になるそう。
自分のもリセットを延々としてました。また、電流も多く消費(80mAくらい)します。
↓対策としてここを参考にしました。
https://ehbtj.com/electronics/instability-measures-for-esp8266/

下記2点でなんとかなりました。
●大容量コンデンサを接続
470μF＋15μF
最初多い方がいいと思って、470μFを2個付けていました。ダメみたいです。。。

●パワーオンシーケンスの確保
R=1 kΩ, C=0.1μFだと安定しなかったので、コンデンサの容量を変えていって、C＝0.2μFで大体安定しました。大体といっているのは起動時にたまに失敗したりします。

確認した手持ちのレギュレータ。
オシロスコープは持っていないので、良し悪しはわかりません。
AMS1117は安く手に入りますが、ESP8266用途では不安定なので対策が必要なのかな？

左：AMS1117、右：BA033CC0T

ADP3338は電圧降下がほぼないみたいで、これを使うのが悩まないで済みそうです。
地元のショップにないので秋月の通販を利用するしかないので、当分このまま。